LEX 'BCONV'
* J-F GARNIER, 1986
       ID #2
       MSG 0
       POLL 0
       ENTRY BSTR
       CHAR #F
       ENTRY BVAL
       CHAR #F
       KEY 'BSTR$'
       TOKEN 4
       KEY 'BVAL'
       TOKEN 5
       ENDTXT
       *
POP1N  EQU #0BD1C
CNFLCT EQU #0BD15
SPLITA EQU #0C6BF
FINITA EQU #0CD03
ARGERR EQU #0BF19
STRHDR EQU #0F09A
EXPR   EQU #0F23C
POP1S  EQU #0BD38
CNVUCR EQU #152A7
RANGE  EQU #1B07C
SHF10  EQU #0C486
FNRTN4 EQU #0F238
DCHXF  EQU #1B223
INFR15 EQU #0C73D
       *
       NIBHEX 8822
BSTR   GOSUB Poparg
       GOSBVL POP1N
       GONC BSTR1
       GOTO Cnflct
BSTR1  D1=D1+ 16
       GOSBVL SPLITA
       GOSBVL FINITA
       GONC BSTR3
BSTR2  GOTO Argerr
BSTR3  GOSUB Infr
       ?B=0 W
       GOYES BSTR4
       ?A#0 S
       GOYES BSTR2
       P= 0
       LC(5) #11
       ?C<A A
       GOYES BSTR2
BSTR4  D=0 W
BSTR5  SETHEX
       D=D+D W
       C=D W
       D=D+D W
       D=D+D W
       D=D+C W
       BSL W
       ?B=0 S
       GOYES BSTR7
BSTR6  D=D+1 W
       B=B-1 S
       ?B#0 S
       GOYES BSTR6
BSTR7  SETDEC
       A=A-1 A
       GONC BSTR5
       SETHEX
       C=D W
       A=0 A
BSTR8  A=A+1 A
       CSRB
       ?ST=1 9
       GOYES BSTR9
       CSRB
       CSRB
       ?ST=1 10
       GOYES BSTR9
       CSRB
BSTR9  ?C#0 W
       GOYES BSTR8
       C=A A
       C=C+C A
       P= 0
       GOSBVL STRHDR
       DSL W
BSTR10 DSRB
       ?ST=1 9
       GOYES BSTR11
       DSRB
       DSRB
       ?ST=1 10
       GOYES BSTR11
       DSRB
BSTR11 C=0 W
       C=D P
       ?ST=1 11
       GOYES BSTR12
       CSRB
       ?ST=1 10
       GOYES BSTR12
       CSRB
       CSRB
BSTR12 A=C B
       LC(2) 10
       ?C>A B
       GOYES BSTR13
       LC(1) 7
       A=A+C B
BSTR13 LC(2) #30
       A=A+C B
       DAT1=A B
       D1=D1+ 2
       D=0 P
       ?D#0 W
       GOYES BSTR10
       A=R1
       D1=A
       GOVLNG EXPR
       *
       NIBHEX 8422
BVAL   GOSUB Poparg
       A=0 W
       GOSBVL POP1S
       B=0 W
       ASRB
       R0=A
       D=0 A
       D=D-1 A
       GOTO BVAL8
BVAL1  A=0 W
       P= 0
       GOSBVL CNVUCR
       D1=D1+ 2
       LCASC '10'
       ?ST=1 9
       GOYES BVAL2
       LCASC '70'
       ?ST=1 10
       GOYES BVAL2
       LCASC '90'
BVAL2  GOSBVL RANGE
       GONC BVAL5
       ?ST=1 11
       GOYES BVAL4
BVAL3  GOTO Argerr
BVAL4  LCASC 'FA'
       GOSBVL RANGE
       GOC BVAL3
       A=A-1 B
BVAL5  LC(2) #30
       A=A-C B
       P= 11
       ?A=0 B
       GOYES BVAL8
       C=D A
       GONC BVAL7
BVAL6  SETDEC
       A=A+A WP
       GOC BVAL3
       ?ST=1 9
       GOYES BVAL7
       A=A+A WP
       GOC BVAL3
       A=A+A WP
       GOC BVAL3
       ?ST=1 10
       GOYES BVAL7
       A=A+A WP
       GOC BVAL3
BVAL7  SETHEX
       C=C-1 A
       GONC BVAL6
       SETDEC
       B=B+A WP
       GOC BVAL3
BVAL8  SETHEX
       C=R0
       D=D+1 A
       ?C=D A
       GOYES BVAL9
       GOTO BVAL1
BVAL9  P= 0
       C=0 A
       LC(2) #14
       A=C A
       SETDEC
       GOSBVL SHF10
       C=0 S
       C=B M
       C=A X
       D1=D1- 16
       GOVLNG FNRTN4
       *
Poparg GOSBVL POP1N
       GONC Popar1
Cnflct GOVLNG CNFLCT
Popar1 GOSBVL DCHXF
       GOC Popar2
Argerr GOVLNG ARGERR
Popar2 D1=D1+ 16
       ST=0 9
       ST=0 10
       ST=0 11
       C=0 A
       LC(1) 2
       ?A#C A
       GOYES Popar3
       ST=1 9
       RTN
Popar3 LC(1) 8
       ?A#C A
       GOYES Popar4
       ST=1 10
       RTN
Popar4 LC(2) 16
       ?A#C A
       GOYES Argerr
       ST=1 11
       RTN
       *
Infr   GOSBVL INFR15
       B=0 S
       ?P= 15
       RTNYES
       ?P# 14
       GOYES Infr1
       C=A A
       C=C+1 A
       GOC Infr1
       BSR WP
Infr1  B=B+B P
       B=0 WP
       GONC Infr2
       B=B-1 WP
       B=B+1 W
       ?B=0 S
       RTNYES
       BSR W
       A=A+1 A
       RTN
Infr2  ?B#0 W
       RTNYES
       A=0 A
       RTN
       END